100 'CZ8FB02をEMM3(ROM)ブ－トにする
101 LIMIT &HE000
110 D$="EMM0:"
120 '
130 PRINT D$;"初期化"
150 POKE &HE000,&HFF 'EMMを埋める値
160 DMA$=HEXCHR$("79 00 E0 FF FF 34 28 CD 03 0D 9A CF 05") 'For EMM0
170 OUT &HD00,0:OUT &HD01,0:OUT &HD02,0                    'For EMM0
180 FORA=1TOLEN(DMA$):OUT &H1F80,ASC(MID$(DMA$,A,1)):NEXT
190 FORA=1TO8:OUT &H1F80,&HCF:OUT &H1F80,&H87:NEXT         '512KByte
200 INIT D$
210 '
220 PRINT"BASICの転送"
230 COPY "0:/BASIC CZ8FB02.Sys" AS D$
240 DEVI$ D$,16,X$,Y$
250 IR=CVI(MID$(X$,&H1E+1,2))*16 'IPL起動の格納開始レコ－ドを算出
260 MID$(X$,&H1E+1,2)=MKI$(IR)   '手抜き注意！
270 MID$(X$,&H0+1,1)=CHR$(1)     '"Bin"にする
280 PRINT"WRITE:IPL FCB"
290 DEVO$ D$,0,X$,Y$             'IPL用FCBの書き込み
300 '
310 DEVI$ D$,IR+&H89,X$,Y$
320 IF MID$(X$,&H3B+1,2)<>HEXCHR$("0E 07") THENPRINT"Err1":END
330 MID$(X$,&H3B+1,2)=HEXCHR$("0E 06")  '06H=EMM
340 IF MID$(X$,&H42+1,2)<>HEXCHR$("38 0E") THENPRINT"Err2":END
350 MID$(X$,&H42+1,2)=HEXCHR$("18 0E")
360 IF MID$(X$,&H5F+1,2)<>HEXCHR$("E6 0F") THENPRINT"Err3":END
370 MID$(X$,&H5F+1,2)=HEXCHR$("3E 09")  '09H=ﾄﾞﾗｲﾌﾞ番号 "EMM9:"
380 PRINT"PATCH:CODE"
390 DEVO$ D$,IR+&H89,X$,Y$
400 '
410 DEVI$ D$,IR+&H8A,X$,Y$
420 IF MID$(Y$,&HF9+1-128,3)<>HEXCHR$("20 20 20") THENPRINT"Err4":END
430 MID$(Y$,&HF9+1-128,3)="EMM"
440 PRINT"PATCH:DRIVE NAME"
450 DEVO$ D$,IR+&H8A,X$,Y$
460 '
470 PRINT"もろもろ転送"
480 COPY "0:/Start up     .Bas" AS D$
490 COPY "0:/Start up data.Sub" AS D$
500 COPY "0:/音訓     変換.DIC" AS D$
510 COPY "0:/FORMAT & COPY.Uty" AS D$
520 COPY "0:/DISK UTILITY .Obj" AS D$
530 COPY "0:/DEVICE DUMP  .Bas" AS D$